Основы jc

import jandcode.jc.*
import jandcode.jc.std.*

class P1 extends ProjectScript {

    void onInclude() {
        project.name = "tutorial-1"

        include(Utils)

        include(Utils).with {
            param1 = "NewValue1"
        }
        include(Utils).param2 = "Val2"

        Utils u = getIncluded(Utils)
        if (u != null) {
            u.param3 = "Q3"
        }

        include(Showlibs)

        cm.add("one", "Первая команда") {
            log("Команда 1 выполнена")
        }

        cm.add("two", "Вторая команда", this.&cmTwo,
                cm.opt("a", "Опция a"),
                cm.opt("b", "", "Опция b с параметром"),
        )

    }

    void cmTwo(CmArgs args) {
        ant.echo(message: "Arguments: ${args}")
        println("Печатаем текст")
        log("Команда 2 выполнена")
    }

    //////

    public static class Utils extends ProjectScript {
        String param1 = "value1"
        String param2 = "value2"
        String param3 = "value3"

        void onInclude() {
            cm.add("util-one", "Первая команда из утилит") {
                showParam()
                log("Команда util-one выполнена")
            }
        }

        void showParam() {
            log "Param1=${param1}"
            log "Param2=${param2}"
            log "Param3=${param3}"
        }
    }

}

jc two -b:1 -a

import jandcode.jc.*

class EmptyProject extends ProjectScript {
    void onInclude() {
    }
}

import jandcode.jc.*

class ProjectInScript extends ProjectScript {

    void onInclude() {
        // текущий проект
        Project p1 = getProject()

        // это groovy, можно писать и так:
        Project p2 = project

        // получение имени проекта
        String s1 = project.getName()
        String s2 = project.name

        // скрипт делегирует методы интерфейса
        // jandcode.jc.Project проекту,
        // поэтому можно писать и так:
        String s3 = getName()
        String s4 = name

        // а это получение пути относительно
        // рабочего  каталог проекта (workdir, wd):
        String wd1 = project.wd("temp")
        String wd2 = wd("temp")
    }

}

// класс скрипта
project.include(jandcode.jc.std.Showlibs)
// класс скрипта, пакет должен быть импортирован
project.include(Showlibs)
// полное имя класса скрипта
project.include("jandcode.jc.std.Showlibs")
// имя файла со скриптом
project.include("./my-script.jc")

// класс скрипта
include(jandcode.jc.std.Showlibs)
// класс скрипта, пакет должен быть импортирован
include(Showlibs)
// полное имя класса скрипта
include("jandcode.jc.std.Showlibs")
// имя файла со скриптом
include("./my-script.jc")

// включаем скрипт первый раз, создается экземпляр JavaProject
JavaProject jm = include(jandcode.jc.std.JavaProject)

// включаем скрипт второй раз, не создается JavaProject,
// просто возвращается предыдущий
JavaProject jm2 = include(jandcode.jc.std.JavaProject)

// еще не включали
JavaProject jm = getIncluded(JavaProject)
assert jm == null

// включаем
include(JavaProject)
jm = getIncluded(JavaProject)
assert jm != null

class Data {
    String f1
    String f2
}
def d = new Data()
d.with {
    f1 = '1'
    f1 = '2'
}

// эквивалентный код без with:
d.f1 = '1'
d.f2 = '2'

include(SomeScript).with {
    someProperty1 = 1
    someMethod2(1)
}

// эквивалентный код без with:
SomeScript sm = include(SomeScript)
sm.someProperty1 = 1
sm.someMethod2(1)

// можно и так:
include(SomeScript).someProperty1 = 1
include(SomeScript).someMethod2(1)

import jandcode.jc.*

class CmInScript extends ProjectScript {

    void onInclude() {

        /* объявление команды 'cm1', без описания.
           код команды - closure
         */
        cm.add("cm1") {
            log("Команда выполнена")
        }

        /* объявление команды 'cm2', с описанием.
           код команды - closure
         */
        cm.add("cm2", "Это команда 2\nОписание может быть\nмногострочным") {
            log("Команда выполнена")
        }

        /* объявление команды 'cm3', с описанием.
           код команды - метод cmMethod
         */
        cm.add("cm3", this.&cmMethod, "Это команда 3")

        /* объявление команды 'cm4', с описанием и опциями.
           код команды - метод cmMethod
         */
        cm.add("cm3", this.&cmMethod, "Это команда 3",
                cm.opt("opt1", false, "boolean опция"),
                cm.opt("opt2", "Также boolean опция"),
                cm.opt("opt3", "", "Опция с параметром"),
        )

    }

    /**
     * Для методов, котрые используются как команды,
     * можно объявить аргумент типа CmArgs, который будет
     * заполнен параметрами командной строки при вызове команды.
     */
    void cmMethod(CmArgs args) {
        log("Команда выполнена")
    }

}

ant.echo(message: "Arguments: ${args}")